1 REM SIMPDISK  
5 CLEAR  1000  
10 CLS  
20 PRINT  TAB(10); "DISCOUNT ANALYSIS":PRINT   
25 PRINT "DISCOUNTS ARE COMMON IN ALMOST ALL BUSINESSES AT ALMOST  
30 PRINT "ALL TIMES. THERE ARE THREE MAJOR TYPES OF QUESTIONS WHICH  
35 PRINT "ARE CONSIDERED IN THIS PROGRAM. THEY ARE:  
40 PRINT "    1. GIVEN A LIST PRICE AND A PER CENT DISCOUNT  
45 PRINT "         DETERMINE THE SELLING PRICE  
50 PRINT "    2. GIVEN A DISCOUNTED PRICE AND A PER CENT DISCOUNT  
55 PRINT "         DETERMINE THE ORIGINAL PRICE  
60 PRINT "    3. GIVEN AN ORIGINAL AND A DISCOUNTED PRICE DETERMINE  
65 PRINT "         THE DISCOUNT %.  
90 PRINT :INPUT "PRESS ENTER TO BEGIN";Z9$  
100 GOSUB  9000  
200 CLS:PRINT  TAB(10); "MENU":PRINT   
205 PRINT "0. QUIT  
210 PRINT "1. DETERMINE SELLING PRICE GIVEN LIST PRICE & % DISCOUNT  
220 PRINT "2. DETERMINE ORIGINAL PRICE GIVEN DISCOUNTED PRICE AND % DISC.  
230 PRINT "3. DETERMINE % DISCOUNT GIVEN ORIGINAL AND DISCOUNTED PRICE  
290 PRINT :INPUT "MAKE YOUR CHOICE";Z9  
295 IF Z9 = 0 THEN END
300 ON  Z9 GOSUB  500,600,700  
310 GOTO  200  
500 REM FIND SELLING PR. GIVEN ORIG PR & % DISCOUNT  
510 CLS:PRINT "SELLING PRICE GIVEN ORIGINAL PRICE & % DISCOUNT  
515 PRINT   
520 INPUT "ORIGINAL PRICE       ";OP  
530 INPUT "% DISCOUNT           ";PD:PD=PD/100  
540 PRINT USING  F$(1);"DISCOUNT AMOUNT",PD*OP  
550 PRINT USING  F$(1);"SELLING PRICE",OP*(1-PD)  
560 PRINT :GOSUB  10100  
570 RETURN   
600 REM FIND ORIGINAL PRICE GIVEN SELL. PR. AND % DISCOUNT  
610 CLS:PRINT "ORIGINAL PRICE GIVEN SELLING PRICE & % DISCOUNT"  
615 PRINT   
620 INPUT "SELLING PRICE        ";SP  
630 INPUT "% DISCOUNT           ";PD:PD=PD/100  
640 PRINT USING  F$(1);"ORIGINAL PRICE IS ",SP/(1-PD)  
650 PRINT USING  F$(1);"DISCOUNT AMOUNT",SP/(1-PD)-SP  
660 PRINT :GOSUB  10100  
670 RETURN   
700 REM DISCOUNT GIVEN ORIGINAL & DISCOUNTED PRICE  
705 CLS  
710 PRINT :PRINT "DISCOUNT GIVEN ORIGINAL AND DISCOUNTED PRICES":PRINT   
720 INPUT "ENTER ORIGINAL PRICE  ";OP  
730 INPUT "ENTER DISCOUNTED PRICE";PD  
740 D=(OP-PD)/OP:D=100*D  
750 PRINT USING  F$(1);"DISCOUNT PERCENTAGE",D  
760 PRINT :GOSUB  10100  
770 RETURN   
9000 REM PRINTING FORMATS  
9010 F$(1)="%                    %   ########.##"  
9099 RETURN   
10100 INPUT "PRESS ENTER TO CONTINUE";Z9$:RETURN   

